commodore.gen.tr

@ECHO OFF


REM bat dosyasinin calistigi klasordeki 7z'ler aranıyor
for %%F in (*.7z ) do (

ECHO %%F tekrar sıkıştırılacak...

CLS
REM burada 7z, zip klasoru altina "icerik" olarak açılıyor
"C:\Program Files\7-Zip\7z" x "%%F" -o"zip\%%F icerik"

REM 7zip arsiv icin gecici "icerik" klasör oluşturdu mu kontrol ediliyor...
IF EXIST "zip/%%F icerik" (

REM klasorun icine bos bir klasor olusturuyoruz
REM boylece 7z arsivinin icerigi uygun bir klasorde kalmaya devam ediyor
REM KLASOR ADINI BURADA DUZENLIYORUZ!
REM ****

MKDIR "zip\%%~nF"
REM ****

REM açılmış olan zip dosyasinin diger klasorune giriyoruz
CD "zip\%%F icerik"

REM Klasorun icinde bulunan her dosyayi ayri ayri zipliyoruz
for %%G in (*.*) do (

CLS
"C:\Program Files\7-Zip\7z" a -tzip "../%%~nF/%%~nG.zip" "%%G" -mx5

REM winrar ile ziplemek için "C:\Program Files\WINRAR\winRar" A -afzip "../%%~nF/%%~nG.zip" "%%G" -m5
REM rarlamak için "C:\Program Files\WINRAR\winRar" A -afrar "../%%~nF/%%~nG.rar" "%%G" -m5

)

REM dosyalar ziplendi, klasorden cikalim
CD ..

REM eger kaynak dosyayi silmek isterseniz alttaki satirin rem'ini silin
REM DEL "%%F" /F /Q

REM zipleri olusturdugumuza gore gecici klasoru silebiliriz
RMDIR "%%F icerik" /S /Q

REM hersey bitti 7z klasorune geri cikalim
CD ..

ECHO %%F dosyasi işlendi, devam ediyoruz.
)
)
ECHO Tarama başarıyla tamamlandı.

PAUSE

@Echo Off
If "%1"=="" Goto Usage
If Not Exist Zip Md Zip
If Not Exist Temp Md Temp

Md Temp\%~n1
7za.exe x "%~n1.7z" -o"Temp\%~n1"
Cd Temp\%~n1
..\..\7za.exe a -tzip "..\..\Zip\%~n1.zip" "*.*" -mx5
Cd ..
Cd ..

Goto End

:Usage
Echo 7z To Zip Converter Utility
Echo Usage: ReCompress FileName
Echo .

:End

@Echo Off
For %%F in (*.7z ) Do Call ReCompress %%F