// C64 Arduino DMA Yazma Programı Demo

// 0-255 arasındaki sayıları sırayla ve 255 sonrasında başa alıp tekrarlayarak 32768-40959 (8000-9FFF) C64

// adreslerine yazar.8 Kbyte yazma işlemidir.

// Kontrol toplamı : 1044480 

int sayi=0; // hex 8000 değerinin alt adres (00) desimal

int say=128;// hex 8000 değerinin üst adres(80) desimali

int data=0;

void setup()

{   

 PORTC=B00001100;   // PC2 High DIR 74245 A dan B ye geçiş (Yazma) tipinde. PC3 High OE . Burada hazırlık yaptık.

 DDRC=B00001100;    // Burada PC2 PC3  OUTPUT yaptık sinyalleri gönderdik. PC2 OUTPUT HİGH da.

                    // PC3 Output (HIGH) yapıldı yani 2 adet 74374 ve 74245 HI-Z yapıldı .C64 ile İZOLASYON.

 PORTB=B00000000;   // Yazmaya gerek yoktu.Açılışta zaten 3 register (B C D portlarının tümü) böyle gelir. 

 DDRB=B00101000;     //PB5 1. 74374 clock ve PB3. 74374 clock OUTPUT ve LOW yapıldı. 

 DDRD=B11111111;   // Port D bütün pinler OUTPUT  

}                     

void loop ()

{   

 //DMA GİRİŞ

 delay (5000);

 while(bitRead(PINB,2)==1); // B2 INPUT LOW olmasını bekle. Buton LOW DMA yı başlatacak.

 while(bitRead(PINC,1)==1); // DMA ya giriş : C1 INPUT BA nın LOW olmasını  bekle.

 delayMicroseconds(5);      // BA LOW oldu. 5 mikrosaniye oyalan.

 DDRB= DDRB | B00000001;    // DMA KİLİTLEME (pin B0) OUTPUT ve LOW yapıldı.

                            // Diğer pinler değişmedi.

              //BİRİNCİ AŞAMA BURADA TAMAMLANDI.                   

 //:::::::::::::::::::::::::::::::::::::::::::

 for (int h=0 ; h<=8191; h++)  // 8 K yazacağız. LOOP başlangıcı.

 {

// 2. AŞAMA DMA YAZMA

// ADRESLER 74374'e  KİLİTLENECEK

  while(bitRead(PINC,1)==0); // C1 INPUT BA nın HİGH olmasını bekle. 

  PORTB=PORTB & B11010111; //1. ve 2. 74374 clocklar LOW yapıldı PB5 ,PB3. B0 DMA low olmaya devam ediyor.(AND işlemi)

 //1.74374 (ALT ADRES YAZILIYOR)           

  PORTD=sayi;         // ALT ADRESİ D ye yükledik

  PORTB=PORTB | B00100000; //PB5 High yapılarak Alt adres 1. 74374 e yüklendi.(OR işlemi)

  //2. 74374 (ÜST ADRES YAZILIYOR)

  PORTD=say;        // ÜST ADRESİ D'ye yükledik.

  PORTB= PORTB |  B00001000; // B3 HIGH yapıldı.Üst adres 2.74374 e yüklendi.

  //YAZILACAK DATANIN HAZIRLIĞI  

  PORTD= data; // yazılacak datayı hazırlama.

  while(bitRead(PINC,0)==0); //   C0 C64 clock high bekle.                       

  asm("nop\n nop\n nop\n nop\n"); // Gecikme.

  DDRB= B00101011;  // R/W PİNİ (B1) HI-Z den OUTPUT'a AÇILDI ve LOW gönderildi.(C64 yazma sinyali).

                    // PBO daki DMA latch  OUTPUT (LOW ) ile korunuyor. PB3 vePB5 CLOCK 1.ve 2. 74374 de OUTPUT durumu korunuyor.

  PORTC=B00000100;  //PC3 LOW yapıldı 2X74374 ve 74245 açıldı (OE LOW). C64 data ve adres BUS'a  yazıldı.                            

                    //PC2 output da HIGH'a devam (data direction 74245).

  asm("nop\n nop\n nop\n nop\n nop\n nop\n");

  asm("nop\n nop\n nop\n nop\n nop\n");      // Gecikme.

 PORTC=B00001100;   // PC3 high yapıldı 2X74374 ve74245 HI-Z durumuna geçti.  

 DDRB= B00101001;   //PB1 R/W pıni INPUT HI_Z yapıldı. C64'e yazma işlemi tamamlandı.DMA low hala korunuyor.

 sayi++;   // adresi bir arttır.

 data++;

 if (((sayi-1) &  B11111111) == B11111111 ){ say++; sayi=0;data=0; } // (255)sayfa geçişi

 }

//::::::::::::::::::::::::::::::::::::::::::

 delay (1000);

 //DMA ÇIKIŞ

 while(bitRead(PINC,1)==1);  //DMA çıkış için C1 pini BA LOW bekle

 delayMicroseconds(5);      //BA LOW oldu. 5 mikrosaniye oyalan.

 DDRB=DDRB & B11111110; // B0 DMA pinini İNPUT yaptık HI-Z. DMA sona erdi.

 while(1);   // Dur,bekle.

}
