// C64 Arduino DMA Okuma-Yazma Programı Demo

// C64 BASİC ROM 40960-49151 (A000-BFFF) arasındaki 8191 adresin 

//okunması ve hemen ardından 32768den başlayarak 8191adrese yazılması

//8 K okuma yazma programı

int alt=0;

int ust=160;   // Okunan adresler başlangıcı

int oku=0;

int sayi=0;

int say=128;   // Yazılan adresler başlangıcı

void setup()

{  

 // Bu Bölüm aynen yazma programından alınmadır.Düzenlemeler..  

 PORTC=B00001100;   // PC2 High DIR 74245 A dan B ye geçiş (Yazma) tipinde. PC3 High OE . Burada hazırlık yaptık.

 DDRC=B00001100;    // Burada sinyalleri gönderdik. PC2 OUTPUT HİGH da.

                    // PC3 Output (HIGH) yapıldı yani 2 adet 74374 ve 74245 HI-Z yapıldı.C64 ile İZOLASYON.

 PORTB=B00000000;   // Yazmaya gerek yoktu.Açılışta zaten 3 register (B C D portlarının tümü) böyle gelir. Bilgi.. 

 DDRB=B00101000;     //PB5 1. 74374 clock ve PB3. 74374 clock OUTPUT ve LOW yapıldı. 

                     //Adres yazmak için sinyaller hazırlanıyor.

 DDRD=B11111111; // HEPSİ OUTPUT 74374ler'e yazılacak.

 }                     

void loop ()

{   

 //DMA GİRİŞ

 delay (5000);

 while(bitRead(PINB,2)==1); // B2 INPUT LOW olmasını bekle. Buton LOW DMA yı başlatacak.

 while(bitRead(PINC,1)==1); // DMA ya giriş : C1 INPUT BA nın LOW olmasını  bekle.

 delayMicroseconds(5);      // BA LOW oldu. 5 mikrosaniye oyalan.

 DDRB= DDRB | B00000001;    // DMA KİLİTLEME (pin B0) OUTPUT ve LOW yapıldı.(OR işlemi)

                            // Diğer pinler değişmedi.

              //BİRİNCİ AŞAMA BURADA TAMAMLANDI.                   

 //:::::::::::::::::::::::::::::::::::::::::::

 // OKUMA BAŞLANGICI

for (int h=0 ; h<=8191; h++)  // 8 Kb okuyacağız ve yazacağız. LOOP başlangıcı.

 { 

PORTC=PORTC & B11111011 ; // C2 LOW yapıldı 74245 yönü B den A ya değiştirildi)

                        // (B= C64. A= ARDUINO:)C64 den Okunacak.

// DMA OKUMA

// ADRESLER 74374'e  KİLİTLENECEK

  while(bitRead(PINC,1)==0); // C1 INPUT BA nın HİGH olmasını bekle. 

  PORTB=PORTB & B11010111; //1. ve 2. 74374 clocklar LOW yapıldı (PB5 ,PB3). B0 DMA low olmaya devam ediyor.(OR işlemi)

 //1.74374 (ALT ADRES YAZILIYOR)           

  PORTD=alt;         // ALT ADRESİ D ye yükledik

  PORTB=PORTB | B00100000; //PB5 High yapılarak Alt adres 1. 74374 e yüklendi.(OR işlemi)

  //2. 74374 (ÜST ADRES YAZILIYOR)

  PORTD=ust;        // ÜST ADRESİ D'ye yükledik.

  PORTB= PORTB |  B00001000; // B3 HIGH yapıldı.Üst adres 2.74374 e yüklendi.

  //OKUNACAK DATANIN HAZIRLIĞI  

  DDRD=B00000000; // HEPSİ INPUT OKUMA. (buraya kadar D pinlerinin hepsi Output idi).

  while(bitRead(PINC,0)==0); //   C0 C64 clock high bekle.

  asm("nop\n nop\n nop\n nop\n nop\n nop\n");  // Gecikme.

  PORTC=PORTC & B11110111;  //PC3 LOW yapıldı 2X74374 ve 74245 açıldı (OE LOW). C64 adres BUS'a  yazıldı.(AND işlemi)                            

                            //PC2 OUTPUT  LOW'a devam (data direction 74245).

  asm("nop\n nop\n nop\n");// Gecikme.

  asm("nop\n nop\n nop\n");

  asm("nop\n nop\n nop\n");

  oku = PIND; // arduino  yazılan adresi okuyor.

  asm("nop\n nop\n");  // Gecikme.

 PORTC=PORTC | B00001000 ;   // PC3 high yapıldı 2X74374 ve74245 HI-Z durumuna geçti.  

  alt++;

 if (((alt-1) &  B11111111) == B11111111 ){ ust++; alt=0;} // (255)sayfa geçişi

 //;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;,

 // YAZMA BAŞLANGICI

 PORTC=PORTC | B00000100 ; // C2 high.74245 A dan B ye YAZMA yapılacak.(Arduinodan C64'e).

 DDRD=B11111111; // D PİNLERİNİN HEPSİ OUTPUT YAPILDI.(hem 74374 lere hem de 74275'e yazma var).

 // DMA YAZMA

// ADRESLER 74374'e  KİLİTLENECEK

  while(bitRead(PINC,1)==0); // C1 INPUT BA nın HİGH olmasını bekle. 

  PORTB=PORTB & B11010111; //1. ve 2. 74374 clocklar LOW yapıldı PB5 ,PB3. B0 DMA low olmaya devam ediyor.(AND işlemi)

 //1.74374 (ALT ADRES YAZILIYOR)           

  PORTD=sayi;         // ALT ADRESİ D ye yükledik

  PORTB=PORTB | B00100000; //PB5 High yapılarak Alt adres 1. 74374 e yüklendi.(OR işlemi)

  //2. 74374 (ÜST ADRES YAZILIYOR)

  PORTD=say;        // ÜST ADRESİ D'ye yükledik.

  PORTB= PORTB |  B00001000; // B3 HIGH yapıldı.Üst adres 2.74374 e yüklendi.

  //YAZILACAK DATANIN HAZIRLIĞI  

   PORTD= oku ; // yazılacak datayı al

  while(bitRead(PINC,0)==0); //   C0 C64 clock high bekle.                       

  asm("nop\n nop\n nop\n nop\n"); // Gecikme.

  DDRB= B00101011;  // R/W PİNİ (B1) HI-Z den OUTPUT'a AÇILDI ve LOW gönderildi.(C64 yazma sinyali).

                    // PBO daki DMA latch  OUTPUT (LOW ) ile korunuyor. PB3 vePB5 CLOCK 1.ve 2. 74374 de OUTPUT durumu korunuyor.

  PORTC=B00000100;  //PC3 LOW yapıldı 2X74374 ve 74245 açıldı (OE LOW). C64 data ve adres BUS'a  yazıldı.                            

                    //PC2 output da HIGH'a devam (data direction 74245).

  asm("nop\n nop\n nop\n nop\n nop\n nop\n");

  asm("nop\n nop\n nop\n nop\n nop\n");      // Gecikme.

 PORTC=B00001100;   // PC3 high yapıldı 2X74374 ve74245 HI-Z durumuna geçti.  

 DDRB= B00101001;   //PB1 R/W pıni INPUT HI_Z yapıldı. C64'e yazma işlemi tamamlandı.DMA low hala korunuyor.

  sayi++; 

 if (((sayi-1) &  B11111111) == B11111111 ){ say++; sayi=0;} // (255)sayfa geçişi

 }

//::::::::::::::::::::::::::::::::::::::::::

  //DMA ÇIKIŞ

 while(bitRead(PINC,1)==1);  //DMA çıkış için C1 pini BA LOW bekle

 delayMicroseconds(5);      //BA LOW oldu. 5 mikrosaniye oyalan.

 DDRB=DDRB & B11111110; // B0 DMA pinini İNPUT yaptık HI-Z. DMA sona erdi.

  while(1);   // Dur,bekle.

}
