sonraki »

[joker_]

Ekranımızı sildik,müzik ekledik,logomuzu bastık,şimdi de logonun altına raster basalım.
  Raster için daha önce linklerini verdiğim kaynaklarda çok detaylı bilgiler mevcut.
  Sadece raster çeken bir rutin yazıcam.Açıklamaları satırların yanında bulabilirsiniz.

Kod:

!to"raster.prg",cbm

                * = $0900	;<--Kodumuzun başlangıç adresi

		jsr $e544	 

		lda #$00	 
		sta $d020	 
		sta $d021	 

;====Burada irq ayarlarımızı yapıyoruz=======

               	sei

	 	lda #$7f
               	sta $dc0d

               	lda #$01
               	sta $d01a

		lda #$00
		sta $dc0e
	
              	lda #$1b
              	sta $d011

		lda #$6d
		sta $d012
		
		lda #<irq
		sta $0314
		lda #>irq
	   	sta $0315
 
              	cli
		jmp *
		
;====irq 'ya girip logomuzu gösteriyoruz====
irq
		inc $d019
;burada üst raster'ı basıyoruz.

		lda #$00		;ekran rengini siyah yapıyoruz
		sta $d020
		sta $d021
		
		ldx #$01		;zamanlamayı tam satır başında 
		dex			;yaklamak için bekleme yapıyoruz
		bne *-1

		ldx #0			
-		lda üst_renk,x		;iç ve dış ekran rengini
		sta $d020		;tablodan okuyup,ilgili register
		sta $d021		;lara yazıyoruz.

		ldy ust_raster_gecikme,x ;burada tek bir satırın sonuna kadar 	
		dey			;çizilmesini bekleyip
		bne *-1

		inx			;tablodaki diğer rengi okuması için counter'ımızı 1 arttırıyoruz.
		cpx #4			;tablo sonuna geldikmi diye kontrol ediyoruz.
		bne -

		ldx #$01
		dex
		bne *-1

		lda #$00		;iç ve dış ekranı tekrar 
		sta $d020		;siyah renk yapıyoruz.
		sta $d021

		lda #$a2		;bir sonraki irq'nun başlayacağı
		sta $d012		;satırı belirtiyoruz.

		lda #<irq1
		sta $0314
		lda #>irq1
	   	sta $0315

		jmp $ea81

irq1
		inc $d019
;burada alt raster'ı basıyoruz.	
		ldx #$06
		dex
		bne *-1

		ldx #0
-		lda alt_renk,x
		sta $d020
		sta $d021

		ldy alt_raster_gecikme,x
		dey
		bne *-1

		inx
		cpx #4
		bne -

		ldx #$02
		dex
		bne *-1

		lda #$00
		sta $d020
		sta $d021

		lda #$6d
		sta $d012

		lda #<irq
		sta $0314
		lda #>irq
	   	sta $0315       
   
		jmp $ea81 

;=========== kodumuzun sonu ======================
üst_renk    
	!by $06,$0e,$03,$01	 

alt_renk
	!by $01,$03,$0e,$06
            
ust_raster_gecikme       
	!by $08, $08, $08, $08	 

alt_raster_gecikme       
	!by $08, $08, $08, $07

[malcomic-xd]

merhaba abi projede banada yer ayırırsan birşeyler yapmak istiyorum birşey sorucam raster dediğin hazır resim mi oluyor hazır resmi ekrana basmayamı raster basma diyorsun ?

[wizofwor]

Raster tekniği, CRT ekranlarda görüntü oluşturmak için kullanılan bir teknik. Bu teknikte elektron tabancası görüntü alanını satırlar halinde tarıyor. Bu tarama esnasında oluşan satırlara da raster line deniyor.


PAL cihazlarda VICII 320 raster satırı üretir ancak bunların 200 tanesi borderların içindedir. Her hangi bir hile hurdaya karışmıyorsak bu 200 satır içinde çalışırız.

VIC'in bize sağladığı bir güzellik, elektron tabancasının hangi satırda olduğunu CIA2'ye bildirmesidir. Bu sayede herhangi bir raster satırına IRQ atayabilir, ve titiz bir programlamayla, renk, ekran modu, VIC bank, karakter seti gibi parametrelerle oynayarak, zamanlamaya da dikkat ederek çeşitli efektler yapabiliriz. Bunlara da raster effect denir. Raster effectlerin en ünlüsü turbo loader'ların çizdiği yükleme hızını gösteren renkli barlardır.

Kısaca: raster basmak = Ekranda raster IRQ tabanlı efekt göstermek

[joker_]

 Ben yazarken wizofwor benden hızlı davranmış.

merhaba abi projede banada yer ayırırsan birşeyler yapmak istiyorum birşey sorucam raster dediğin hazır resim mi oluyor hazır resmi ekrana basmayamı raster basma diyorsun ?

 Yok kardeşim raster hazır resim değil.Ekranın tarama esnasındaki her bir satırı diyebiliriz kısaca.

 Sana bu konuda nightlord'un bu tutorialini tavsiye ederim.Çok detaylı anlatmış nightlord.

http://nightnetwork.org/writings_tr/c64_grafik_programlama/chunk/index.html


 Bizim burada yaptığımız ise tarama esnasında,istediğimiz satıra gelince,o satırın rengini değiştirmek.

  Şöyle anlatayım,ekran yukarıdan çizilmeye başlıyor,diyelim iç ve dış ekran rengini,siyah olarak çiziyoruz.Biz raster bar yapmak isteğimiz satırın tam başında ekranın iç ve dış rengini istediğimiz bir renkle değiştiriyoruz.Diğer satırın başına geldiğimizde yine renk değiştiriyoruz,diğer satırın başından başka bir renk veriyoruz,kaç satır istiyorsak o kadar satırda bu işlemi tekrar ediyoruz.Daha sonra ekran rengini tekrar eski haline geitiriyoruz.

  Örnekte dikkat edersen,raster renklerini bir tablodan okuyoruz.Kodun en sonundaki  üst_renk  ve   alt_renk  yazan tablolardaki renk değerlerini değiştirip,compile edersen,ekrandaki renklerin değiştiğini görürsün.

 Bu şekilde ekranımızın istediğimiz bir yerinde renkli çubuklar oluşturuyoruz.Bu işlemede raster çekmek veya raster bar deniyor.